NeHe的opengl教程delphi版(4)----旋转

上一节中教给您三角形和四边形的着色。这一课将教您如何将这些彩色对象绕着坐标轴旋转。
其实只需在上节的代码上增加几行就可以了。下面将整个例程重写一遍。方便您知道增加了什么，修改了什么。
增加两个变量来控制这两个对象的旋转。这两个变量加在程序的开始处其他变量的后面( bool fullscreen=TRUE;下面的两行)。它们是浮点类型的变量，使得我们能够非常精确地旋转对象。浮点数包含小数位置，这意味着我们无需使用1、2、3...的角度。你会发现浮点数是OpenGL编程的基础。新变量中叫做 rtri 的用来旋转三角形， rquad 旋转四边形。

Var

   ……

   rtri             : GLfloat;          // 用于三角形的角度 ( 新增 )
   rquad            : GLfloat;          // 用于四边形的角度 ( 新增 )

……

然后修改 glDraw()如下：

PRocedure glDraw();
Begin
   glClear(GL_COLOR_BUFFER_BIT Or GL_DEPTH_BUFFER_BIT); // 清除屏幕和深度缓存
   glLoadIdentity();                    // 重置当前的模型观察矩阵

   //下一行代码是新的。glRotatef(Angle,Xvector,Yvector,Zvector)负责让对象绕某个轴旋转。
   //这个命令有很多用处。 Angle 通常是个变量代表对象转过的角度。
   //Xvector , Yvector 和 Zvector 三个参数则共同决定旋转轴的方向。
   //比如(1,0,0)所描述的矢量经过X坐标轴的1个单位处并且方向向右。
   //(-1,0,0)所描述的矢量经过X坐标轴的1个单位处，但方向向左。
   //D. Michael Traub:提供了对 Xvector , Yvector 和 Zvector 的上述解释。
   //为了更好的理解X, Y 和 Z的旋转，我举些例子...

   //X轴－您正在使用一台台锯。锯片中心的轴从左至右摆放(就像OpenGL中的X轴)。
   //尖利的锯齿绕着X轴狂转，看起来要么向上转，要么向下转。
   //取决于锯片开始转时的方向。这与我们在OpenGL中绕着X轴旋转什么的情形是一样的。
   //(译者注：这会儿您要把脸蛋凑向显示器的话，保准被锯开了花 ^-^。)

   //Y轴－假设您正处于一个巨大的龙卷风中心，龙卷风的中心从地面指向天空(就像OpenGL中的Y轴)。
   //垃圾和碎片围着Y轴从左向右或是从右向左狂转不止。
   //这与我们在OpenGL中绕着Y轴旋转什么的情形是一样的。

   //Z轴－您从正前方看着一台风扇。风扇的中心正好朝着您(就像OpenGL中的Z轴)。
   //风扇的叶片绕着Z轴顺时针或逆时针狂转。这与我们在OpenGL中绕着Z轴旋转什么的情形是一样的。

   glTranslatef(-1.5, 0.0, -6.0);       // 左移 1.5 单位，并移入屏幕 6.0
   //下面的一行代码中，如果rtri等于7，我们将三角形绕着Y轴从左向右旋转7 。
   //您也可以改变参数的值，让三角形绕着X和Y轴同时旋转。

   glRotatef(rtri, 0.0, 1.0, 0.0);      // 绕Y轴旋转三角形 ( 新增 )

   //下面的代码没有变化。在屏幕的左面画了一个彩色渐变三角形，并绕着Y轴从左向右旋转
   glBegin(GL_TRIANGLES);               // 绘制三角
   glColor3f(1.0, 0.0, 0.0);            //设置当前色为红色
   glVertex3f(0.0, 1.0, 0.0);           // 上顶点
   glColor3f(0.0, 1.0, 0.0);            //设置当前色为绿色
   glVertex3f(-1.0, -1.0, 0.0);         // 左下
   glColor3f(0.0, 0.0, 1.0);            //设置当前色为蓝色
   glVertex3f(1.0, -1.0, 0.0);          // 右下
   glEnd();                             // 三角形绘制结束

   //您会注意下面的代码中我们增加了另一个glLoadIdentity()调用。
   //目的是为了重置模型观察矩阵。
   //如果我们没有重置，直接调用glTranslate的话，会出现意料之外的结果。
   //因为坐标轴已经旋转了，很可能没有朝着您所希望的方向。
   //所以我们本来想要左右移动对象的，就可能变成上下移动了，取决于您将坐标轴旋转了多少角度。
   //试试将glLoadIdentity() 注释掉之后，会出现什么结果。

   //重置模型观察矩阵之后，X，Y，Z轴都以复位，我们调用glTranslate。
   //您会注意到这次我们只向右一了1.5单位，而不是上节课的3.0单位。
   //因为我们重置场景的时候，焦点又回到了场景的中心(0.0处)。
   //这样就只需向右移1.5单位就够了。
   //当我们移到新位置后，绕X轴旋转四边形。正方形将上下转动。

   glLoadIdentity();                    // 重置模型观察矩阵
   glTranslatef(1.5, 0.0, -6.0);        // 右移1.5单位,并移入屏幕 6.0
   glRotatef(rquad, 1.0, 0.0, 0.0);     // 绕X轴旋转四边形 ( 新增 )

   glBegin(GL_QUADS);                   // 绘制正方形
   glColor3f(0.6, 0.2, 2.0);            //设置当前色为紫色
   glVertex3f(-1.0, 1.0, 0.0);          // 左上
   glVertex3f(1.0, 1.0, 0.0);           // 右上
   glVertex3f(1.0, -1.0, 0.0);          // 左下
   glVertex3f(-1.0, -1.0, 0.0);         // 右下
   glEnd();                             // 正方形绘制结束
   //下两行是新增的。
   //倘若把 rtri 和 rquad 想象为容器，
   //那么在程序的开始我们创建了容器(rtri , 和rquad )。
   //当容器创建之后，里面是空的。
   //下面的第一行代码是向容器中添加0.2。
   //因此每次当我们运行完前面的代码后，都会在这里使 rtri 容器中的值增长0.2。
   //后面一行将 rquad 容器中的值减少0.15。
   //同样每次当我们运行完前面的代码后，都会在这里使 rquad 容器中的值下跌0.15。
   //下跌最终会导致对象旋转的方向和增长的方向相反。
   rtri := rtri + 0.2;                  // 增加三角形的旋转变量(新增)
   rquad := rquad - 0.15;               // 减少四边形的旋转变量(新增)

End;