Asp+Rss阅读器制作第1/2页

<!--#include file="conn.asp"-->
<%
'******************************
'文件名：index.asp
'功 能：RSS阅读器显示页面
'日 期：2006-6-19
'编 程：Cloud.L
'******************************
Response.contentType="application/xml;charset=gb2312"
%>
<?xml version="1.0" encoding="gb2312"?>
<rss version="2.0">
<channel>
<rssname><%=SiteName%></rssname>
<author><%=Author%></author>
<mail><%=Mail%></mail>
<%
Sql="select top 20 * from [SIHRT_Rss] order by Rss_Date desc,Rss_ID desc"
Set Rs=Server.CreateObject("Adodb.Recordset")
Rs.open Sql,Conn,1,1
if Rs.eof and Rs.bof then
  Response.Write "<listitems><nodata>无列表数据</nodata></listitems>"
else
  Response.Write "<listitems>"
  do while not Rs.eof
  Rss_Cont=replace(Rs("Rss_Cont"),"<br>","")
%>
  <item>
   <rssid><%=Rs("Rss_ID")%></rssid>
   <title><%=Rs("Rss_Title")%></title>
   <postdate><%=Rs("Rss_Date")%></postdate>
   <content><![CDATA[<%=Rss_Cont%>]]></content>
  </item>
<%
  Rs.movenext
  loop
  Response.Write "</listitems>"
end if
RsClose
Connclose
%>

</channel>
</rss>

<!--#include file="Const.asp"-->
<%Response.Buffer=True%>
<%
'******************************
'文件名：Conn.asp
'功 能：RSS阅读程序与数据库连接文件
'日 期：2006-6-18
'编 程：Cloud.L
'******************************
Dim ConnStr,Conn
'Create Connection
ConnStr="Provider=Microsoft.Jet.OLEDB.4.0;Data Source="&Server.MapPath(DataPath)
Set Conn=Server.CreateObject("Adodb.Connection")
Conn.open ConnStr


'Close Rs
Sub RsClose
Rs.Close
Set Rs=nothing
End Sub

'Close Conn
Sub ConnClose
Conn.Close
Set Conn=nothing
End Sub
%>

<%
'******************************
'文件名：Const.asp
'功 能：定义RSS阅读程序常量
'日 期：2006-6-18
'编 程：Cloud.L
'******************************
Const DataPath="Data/RssData.mdb"
Const SiteName="SIHRT--RSS阅读器"
Const Author="Cloud.L"
Const Mail="Sihrt@163.com"

%>