SQL Server误区30日谈 第26天 SQL Server中存在真正的“事务嵌套

误区 #26: SQL Server中存在真正的“事务嵌套”
错误

嵌套事务可不会像其语法表现的那样看起来允许事务嵌套。我真不知道为什么有人会这样写代码，我唯一能够想到的就是某个哥们对SQL Server社区嗤之以鼻然后写了这样的代码说：“玩玩你们”。
让我更详细的解释一下，SQL Server允许你在一个事务中开启嵌套另一个事务,SQL Server允许你提交这个嵌套事务，也允许你回滚这个事务。
但是，嵌套事务并不是真正的“嵌套”，对于嵌套事务来说SQL Server仅仅能够识别外层的事务。嵌套事务是日志不正常增长的罪魁祸首之一因为开发人员以为回滚了内层事务，仅仅是回滚内层事务。
但实际上当回滚内层事务时，会回滚整个事务，而不是仅仅是内层。这也是为什么我说嵌套事务并不存在。
所以作为开发人员来讲，永远不要对事务进行嵌套。事务嵌套是邪恶的。
如果你不相信我说的，那么通过下面的例子就就会相信。创建完数据库和表之后，每一条记录都会导致日志增加8K。

复制代码 代码如下:

CREATE DATABASE NestedXactsAreNotReal;
GO
USE NestedXactsAreNotReal;
GO
ALTER DATABASE NestedXactsAreNotReal SET RECOVERY SIMPLE;
GO
CREATE TABLE t1 (c1 INT IDENTITY, c2 CHAR (8000) DEFAULT 'a');
CREATE CLUSTERED INDEX t1c1 ON t1 (c1);
GO
SET NOCOUNT ON;
GO

复制代码 代码如下:

BEGIN TRAN OuterTran;
GO
INSERT INTO t1 DEFAULT Values;
GO 1000
BEGIN TRAN InnerTran;
GO
INSERT INTO t1 DEFAULT Values;
GO 1000
SELECT @@TRANCOUNT, COUNT (*) FROM t1;
GO

复制代码 代码如下:

ROLLBACK TRAN InnerTran;
GO

复制代码 代码如下:

消息 6401，级别 16，状态 1，第 2 行
无法回滚 InnerTran。找不到该名称的事务或保存点。

复制代码 代码如下:

ROLLBACK TRAN;
GO
SELECT @@TRANCOUNT, COUNT (*) FROM t1;
GO

复制代码 代码如下:

BEGIN TRAN OuterTran;
GO
BEGIN TRAN InnerTran;
GO
INSERT INTO t1 DEFAULT Values;
GO 1000
COMMIT TRAN InnerTran;
GO
SELECT COUNT (*) FROM t1;
GO

复制代码 代码如下:

ROLLBACK TRAN OuterTran;
GO
SELECT COUNT (*) FROM t1;
GO

复制代码 代码如下:

BEGIN TRAN OuterTran;
GO
BEGIN TRAN InnerTran;
GO
INSERT INTO t1 DEFAULT Values;
GO 1000
DBCC SQLPERF ('LOGSPACE');
GO

复制代码 代码如下:

COMMIT TRAN InnerTran;
GO
CHECKPOINT;
GO
DBCC SQLPERF ('LOGSPACE');
GO

复制代码 代码如下:

COMMIT TRAN OuterTran;
GO
CHECKPOINT;
GO
DBCC SQLPERF ('LOGSPACE');
GO