需求來源:
客戶要求[某些特定的表]能[自定義預警報告].
(在特定的表上)用戶可定義某些字段有修改時,向有關用戶發出消息警報<內容大致是 xx 單據的 xx 單號的xx字段由 old 變為了 new>. 最終目的是由消息控制模塊向消息接收人報告這一變更.
基礎知識:
columns_updated()是一個僅可在 insert or update trigger 中調用的方法.
該方法返回 一個 varbinary 的值, 存儲了當次insert 或是 update 觸發器所對應的記錄在哪些字段上發生了inserted or updated.在sqlserver 的聯機幫助[create trigger]和[if update] 中 有對 columns_updated () 方法的簡要描述.
公司要求用trigger 實現: (為每個[特定的表]編寫一個特定的update 觸發器.)
主要難點是窮舉 if update(column)的方法不可行.其他業務實現無問題.
后來仔細琢磨columns_updated() 所返回的值,問題得到解決.
這裡只是講述對columns_updated()所返回的值的解析和運用. 就不考慮用戶指定變更字段及插入記錄到消息表的那部分實現過程了.
--測試數據準備.
if exists(select * from sysobjects where id=object_id(n'[dbo].[t_test]') and xtype = 'u')
drop table t_test
go
create table t_test (
f_id int identity(1, 1) primary key,
f_char char(8) default '',
f_varchar varchar(8) default '',
f_nvarchar nvarchar(8) default '',
f_datetime datetime default getdate(),
f_int int default 0,
f_bigint bigint default 0,
f_decimal decimal(18, 6) default 0.00,
f_number numeric(18, 6) default 0.00,
f_float float default 0.00
)
go
insert into t_test (f_char) values('001')
insert into t_test (f_char) values('002')
go
--編寫update 觸發器
if exists(select * from sysobjects where id=object_id(n'[dbo].[tri_test_upd]') and objectproperty(id,n'istrigger')=1)
drop trigger tri_test_upd
go
create trigger tri_test_upd on t_test --with encryption
for update
as
declare @irowcnt int
set @irowcnt = @@rowcount
if @irowcnt < 1
return
declare
@stable varchar(128),
@spkname varchar(32),
@scolname varchar(128)
declare
@icolcnt int,
@icolid int
declare
@i tinyint,
@j tinyint,
@isegment tinyint,
@ival tinyint,
@ilog2 tinyint
declare
@ssql varchar(8000)
set @stable = 't_test'
set @spkname = 'f_id'
-- 求得當前表列個數
select @icolcnt = count(1) from syscolumns where id = object_id(@stable)
-- 以8 個字段為一小段
set @isegment = case
when @icolcnt / 8 = @icolcnt / 8.0
then
@icolcnt / 8
else
@icolcnt / 8 + 1
end
-- 將數據存入 臨時表
select * into #inserted from inserted
select * into #deleted from deleted
-- 中間處理數據用
create table #temp(
f_pkval varchar(254) not null primary key,
f_oldval varchar(254),
f_newval varchar(254)
)
set @i = 0
while @i < @isegment
begin
if @icolcnt < 9
set @ival= columns_updated()
else
set @ival= substring(columns_updated(), @i + 1, 1)
-- 等於0, 則表示當前小節所對應的8個字段無一被改.
if @ival = 0
begin
set @i = @i + 1
continue
end
while @ival > 0
begin
set @j = 0
set @ilog2 = @ival / 2
while @ilog2 > 0
begin
set @j = @j + 1
set @ilog2 = @ilog2 / 2
end
-- 得到被update 的 列id
set @icolid = 8 * @i + @j + 1
-- 將update列名 賦予 @scolname
select @scolname = s.name
from inserted as i,
deleted as d,
syscolumns as s
where i.f_id = d.f_id
and s.id = object_id(@stable)
and s.colid = @icolid
truncate table #temp
-- 拼成動態語句
set @ssql = 'insert into #temp (f_pkval, f_oldval, f_newval) ' +
'select convert( varchar(200), i.' + @spkname + '), ' +
'convert( varchar(200), d.' + @scolname + '), ' +
'convert( varchar(200), i.' + @scolname + ') ' +
'from #inserted as i, #deleted as d ' +
'where i.' + @spkname + ' = d.' + @spkname +
' and i.' + @scolname + ' <> d.' + @scolname
exec(@ssql)
-- 測試輸出
select f_pkval, @scolname as f_column_name, f_oldval, f_newval from #temp
-- 實際上用 將信息處理后插入消息表
/*
.....
insert into t_message(....)
select 要組織的內容
from #temp
*/
set @ival = @ival - power(2, @j)
end
set @i = @i + 1
end
drop table #inserted
drop table #deleted
drop table #temp
go
-- 測試數據
update t_test set f_datetime = getdate(), f_float = 0.0123, f_int= 1
-- 上面update 語句共修改了三個列
-- 實際輸出
1.)
1 f_int 0 1
2 f_int 0 1
2.)
1 f_datetime may 15 2004 5:30pm may 15 2004 5:31pm
2 f_datetime may 15 2004 5:30pm may 15 2004 5:31pm
3.)
1 f_float 0 0.0123
2 f_float 0 0.0123
-- 算法
columns_updated()方法返回的 varbinary,是以每個小節存儲8個字段(的修改狀態)的方式記錄了當前觸發器所有列的修改情形.因此程序以8個字段為一片段來循環處理所有字段.
set @ival= substring(columns_updated(), @i + 1, 1)
程序用上面語句將一小節轉化為整型. 測試發現:
當且謹當這一小片只有一個字段有修改時
1,@ival = 1 = 2^(1-1);
2,@ival = 2 = 2^(2-1);
3,@ival = 4 = 2^(3-1);
4,@ival = 8 = 2^(4-11);
5,@ival = 16 = 2^(5-1);
6,@ival = 32 = 2^(6-1);
7,@ival = 64 = 2^(7-1);
8,@ival = 128 = 2^(8-1);
而當且謹當1,2個字段有修改時:
@ival = 2^(1-1) + 2^(2-1) = 3;
而第 2,5,8 三個字段有修改時:
@ival = 2^(2-1) + 2^(5-1) + 2^(8-1) = 146;
...
當8個字段都有修改時:
@ival = 2^(1-1) + 2^(2-1) + ... + 2^(8-1) = 255;
也就是說 無論怎樣修改,@ival的值,不外乎是2^n - 1(n>0 and n <9, int)這一數組型成的[和組合](組合時每個數組成員最多出現一次).因此反過來推算: 對 @ival 按 2^n分解, 就可算得被修改列的列表.
至此, 完成了整個trigger 的算法.
