用vbscript合并多个文本文件的代码

2020-06-26 18:08:46

字体：大中小

来源：转载

供稿：网友

问：
嗨，Scripting Guy！在命令提示符中，可以执行命令“copy a.txt+b.txt ab.txt”来提取 a.txt 和 b.txt 的内容，然后将它们合并到名为 ab.txt 的新文件中。可以使用脚本来实现相同的操作吗？

-- DL

答：
嗨，DL。在昨天的专栏文章中，我们探讨了有关文本文件的问题；更具体地讲，我们讨论如何使用脚本来修改 .INI 文件。我们提到，这种解决方法尽管不是很巧妙，但可以达到目的。就今天的问题来说，同样是这种情况。我们可以使用脚本来合并文本文件吗？是的，可以。只不过有一点繁琐，但效果很好。

我们所遇到的难题是，WSH 和 VBScript 都无法通过一条命令来合并文本文件，例如，objFile.AddTextFiles("file1.log","file2.log")。这有点让人失望，但我们不会就此罢手，我们依然可以合并文本文件；只不过需要多执行几个步骤罢了。例如，要将 File1.log 和 File2.log 合并为一个文件（我们将其命名为 Output.txt），需要先读取 File1.log，将该文件的内容附加到 output.txt 末尾，然后读取 File2.log，再将该文件的内容附加到 Output.txt 末尾。事实上，我们必须使用类似下面的脚本：

复制代码代码如下:

	
	Const ForReading = 1  
	
	Set objFSO = CreateObject("Scripting.FileSystemObject")  
	Set objOutputFile = objFSO.CreateTextFile("output.txt")  
	
	Set objTextFile = objFSO.OpenTextFile("c:/logs/file1.log", ForReading)  
	
	strText = objTextFile.ReadAll  
	objTextFile.Close  
	objOutputFile.WriteLine strText  
	
	Set objTextFile = objFSO.OpenTextFile("c:/logs/file2.log ", ForReading)  
	
	strText = objTextFile.ReadAll  
	objTextFile.Close  
	objOutputFile.WriteLine strText  
	
	objOutputFile.Close 

正如您所看到的一样，该脚本并不是特别复杂。首先，我们定义一个常量 (ForReading)，用于打开每个日志文件。接下来，创建一个 FileSystemObject（用于处理文本文件的脚本技术）实例，并使用 CreateTextFile 方法创建一个名为 Output.txt 的新文件。

然后，打开第一个文件 (C:/Logs/File1.log) 来读取其中的内容。我们使用 ReadAll 方法读入整个文本文件，并将该信息存储在变量 strText 中。然后，关闭 File1.log，并使用 WriteLine 方法将刚读入的信息附加到新文件 Output.txt 的末尾。接下来，对下一个文件 (C:/Logs/File2.log) 执行相同的过程。读入第二个文件后，Output.txt 将包含第一个文件以及第二个文件中的所有信息。哈哈，我们成功了！

我们知道您在想什么：不错，尽管上述脚本可以实现目的，但问题是您必须“事先”知道文件夹 C:/Logs 中所有文件的名称。那么，编写一个脚本以获取 C:/Logs 中的所有文件并将它们合并在一起，岂不是更好？嗯，我们还未曾这样想过。您所说的是不是类似下面的脚本：

Const ForReading = 1

Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objOutputFile = objFSO.CreateTextFile("output.txt")

strComputer = "."
Set objWMIService = GetObject("winmgmts://" & strComputer & "/root/cimv2")

Set FileList = objWMIService.ExecQuery _
    ("ASSOCIATORS OF {Win32_Directory.Name='C:/Logs'} Where " _
        & "ResultClass = CIM_DataFile")

For Each objFile In FileList
    Set objTextFile = objFSO.OpenTextFile(objFile.Name, ForReading)
    strText = objTextFile.ReadAll
    objTextFile.Close
    objOutputFile.WriteLine strText
Next

objOutputFile.Close

实际上，我们在此处执行的全部操作是获取 C:/Logs 文件夹中所有文件的集合；这是通过以下 WMI Associators of 查询实现的：

Set FileList = objWMIService.ExecQuery _
    ("ASSOCIATORS OF {Win32_Directory.Name='C:/Logs'} Where " _
        & "ResultClass = CIM_DataFile")

在获取这一集合后，我们可以立即使用 For-Each 循环打开每个文件并读入其中的文本（使用 ReadAll 方法，与上文中的代码相同）。然后关闭该文件，将文本附加到输出文件的末尾。接下来再执行一次循环，对集合中的下一个文件执行相同的过程。只需片刻，就可以将 C:/Logs 中所有文件的所有文本提取出来，并将它们合并为一个名为 output.txt 的新文件。整个过程就是这么简单。

上一篇：用vbs返回 Internet Explorer 的下载控件和 Applet 的列表

下一篇：用vbscript防止本地用户更改其密码